!   TITLE:  rear_cover.mac (ISS)
!
!---------------------------------------------------------------------------
!       Rev -       08/29/2000      J. Rinaldi
!---------------------------------------------------------------------------
!
!   This macro creates the rear cover, P/N 315A073, on the OGA recirculation
!   pump motor assembly, end unit P/N CU09616051.
!
!   ctrearc:        Cartesian Rear Cover Coordinate System
!   cylrearc:       Cylindrical Rear Cover Coordinate System
!   sphrearc:       Spherical Rear Cover Coordinate System
!
!
!******************************* TABLE OF CONTENTS **************************
!
!       Model Assembly Preparation
!
!   1.  Parameter List
!   2.  Model Coordinate System
!   3.  Material and Element Type
!   4.  Solid Model
!
!
!***************************** END Table of Contents ************************
!
!
!
!************************** Model Assembly Preparation **********************
!
!
mod_assemb_prep                         ! prepare database for assembly
!
!
/title,Rear Cover / 315A073
!
!
/units,bin                              ! British/inch
!
!
!**************************** End Model Preparation *************************
!
!
!
!<<<<<<<<<<<<<<<<<<<<<<<< 1.  Parameter List >>>>>>>>>>>>>>>>>>>>>>>>>>
!
!
rear_cover.parm                 ! name of parameter file
!
!
!<<<<<<<<<<<<<<<<<<<< 2.  Model Coordinate Systems >>>>>>>>>>>>>>>>>>>>
!
!
mod_coord_system,CShs0,0,0,l100,0,0,0
!
!
!<<<<<<<<<<<<<<<<<<<< 3.  Material and Element Type >>>>>>>>>>>>>>>>>>>
!
!
!---------------------- Material Properties --------------------
!
UIMP,2,EX, , ,29.0E6,                   ! Material:  304L CRES
UIMP,2,DENS, , ,.286/386.4,
UIMP,2,NUXY, , ,0.27,
!
!---------------------------------------------------------------
!
!
!------------------------- Element Type ------------------------
!
ET,3,shell63
ET,4,solid45
!
!---------------------------------------------------------------
!
!
!<<<<<<<<<<<<<<<<<<<<<<<<<<< 4.  Solid Model >>>>>>>>>>>>>>>>>>>>>>>>>>
!
!
!---------------------- 4.1  Cylindrical Sections ---------------------
!
csys,cylrearc
!
*do,i,0,270,90              ! create 1st area (r2)
    k,,r2,i,0
*enddo
!
create_area,1
!
*do,i,0,270,90              ! create 2nd area (r5)
    k,,r5,i,0
*enddo
!
create_area,1
!
asba,am-1,am,,delete,keep   ! partition areas
!
init_entity_num
!
*do,i,0,270,90              ! create 3rd area (r3)
    k,,r3,i,0
*enddo
!
create_area,1
!
asba,am-2,am,,delete,keep   ! partition areas
!
init_entity_num
!
*do,i,0,270,90              ! create 4th area (r4)
    k,,r4,i,0
*enddo
!
create_area,1
!
asba,am-2,am,,delete,keep
!
init_entity_num
!
*do,i,0,270,90              ! create 5th area (r1)
    k,,r1,i,0
*enddo
!
create_area,1
!
asba,am-2,am,,delete,keep
!
init_entity_num
!
lplot
!
!---------------------- 4.2  Cylindrical Sections ---------------------
!
csys,cylrearc
!
k,,1.5*r2,0,0                   ! horizontal cut
k,,1.5*r2,180,0
!
create_lines
!
asbl,all,lm,,delete,delete
!
init_entity_num
!
k,,1.5*r2,90,0                  ! vertical cut
k,,1.5*r2,270,0
!
create_lines
!
asbl,all,lm,,delete,delete
!
init_entity_num
!
lplot
!
!----------------------- 4.3  Mounting Sections -----------------------
!
csys,ctrearc
!
*do,i,0,120,60
    !
    *if,i,gt,0,then
        create_cs,0,'mntcs%i%',0,0,0,0,i,0,0
    *endif
    !
    k,,1.5*r2,wgap/2,0
    k,,-1.5*r2,wgap/2,0
    !
    create_lines
    !
    k,,1.5*r2,-wgap/2,0
    k,,-1.5*r2,-wgap/2,0
    !
    create_lines
    !
    lsel,s,line,,lm-1,lm,1
    cm,lset1,line
    !
    init_entity_num
    !
    csys,cylrearc
    asel,u,loc,x,0,r1
    !
    asbl,all,lset1,,delete,delete
    !
    init_entity_num
    !
    csys,cylrearc
*enddo
!
lplot
!
!------------------------ 4.4  Create Volumes -------------------------
!
csys,cylrearc
!
*do,i,0,270,90
    asel,s,loc,x,r5,r2
    asel,r,loc,y,i,i+90
    asel,r,loc,z,0
    !
    aadd,all
*enddo
!
init_entity_num
!
aadd,am-3,am-33,am-79
aadd,am-2,am-9,am-77
aadd,am-1,am-32,am-76
aadd,am,am-8,am-78
!
aadd,am-67,am-102,am-5
aadd,am-103,am-29,am-71
aadd,am-66,am-101,am-28
aadd,am-4,am-100,am-70
!
init_entity_num
!
*do,i,0,270,90
    lsel,s,loc,x,0.98*r2,r2
    lsel,r,loc,y,i,i+90
    lsel,r,loc,z,0
    !
    lcomb,all
*enddo
!
init_entity_num
!
asel,s,area,,am-7
asel,a,area,,am-2,am,1
!
msh_algorithm,1,1,,1,,,3,4,0.15,0.25,2,,,,,,
!
init_entity_num
!
asel,s,area,,am-56,am-55,1
asel,a,area,,am-32,am-31,1
!
msh_algorithm,1,1,,1,,,3,4,0.090,0.25,2,,,,,,
!
init_entity_num
!
asel,u,area,,am-6,am-3,1
asel,u,area,,am-2,am,1
asel,u,area,,am-7
asel,u,area,,am-56,am-55,1
asel,u,area,,am-32,am-31,1
!
msh_algorithm,1,1,,1,,,3,4,0.10,0.25,2,,,,,,
!
init_entity_num
!
type,4
mat,2
!
extrude_aset,l1                     ! 1st extrude
!
init_entity_num
!
esize,,3
!
asel,s,loc,y,30
asel,a,loc,y,150
asel,a,loc,y,210
asel,a,loc,y,330
!
asel,a,area,,am-231,am-211,10
asel,a,area,,am-161,am-141,10
asel,a,area,,am-226,am-206,10
asel,a,area,,am-156,am-136,10
!
asel,r,loc,z,l1
!
extrude_aset,l2-l1                  ! 2nd extrude
!
init_entity_num
!
!
csys,cylrearc
!
asel,s,loc,z,0
asel,r,loc,x,r4,r3
asel,u,area,,am-378,am-375,1
!
esize,,1
!
extrude_aset,-l4                    ! 3rd extrude
!
init_entity_num
!
lplot
!
finalize_model_data