!  TITLE: mtrx_pr_test.mac (VERIFICATION)
!
!---------------------------------------------------------------------------
!  Rev -   03/04/02    J. Judd
!---------------------------------------------------------------------------
! OBJECTIVE:
!   Tests mtrx_pr.mac which formats and prints matrix(es)
!
!  COMMAND SYNTAX:
!    mtrx_pr_test
!
!  ARGUMENTS:
!    none
!---------------------------------------------------------------------------
fini
/clear,start
/prep7
*DIM,model,char,5
*DIM,X,array,5,5
model(1)='nut','bolt','boltlock','hand','arm'
X(1,1)=11,21,31,41,51
X(1,2)=12,22,32,42,52
X(1,3)=13,23,33,43,53
X(1,4)=14,24,34,44,54
X(1,5)=15,25,35,45,55

!-----------------------------------------------------------------------
!- 
/output,nuts,txt   !Do /output twice if want to include filename in header
/output,nuts,txt,,append
/COM,
/COM,Parts      Mode1  Mode2  Mode3  Mode4  Mode5
/COM,---------------------------------------------
/output

mtrx_pr,'nuts','txt',1,'model',1,1,5,1,'%-8C','X',1,1,5,5,'%6I'
!                  (1)      (2)     (3)  (4)  (5)  (6)  (7)  (8)   (9)  
!   mtrx_pr,'fname','fileext',appYN,'M1',FrR1,FrC1,ToR1,ToC1,'Fmt1'
!                                   ...  'M2',FrR2,FrC2,ToR2,ToC2,'Fmt2'
!                                        (10) (11) (12) (13) (14)  (15)
/output,nuts,txt,,append
/COM,   
/COM,
/COM,This file was created by mtrx_pr_test.mac
/COM,   
/COM,
/output

*ASK,stop,(Look at nuts.txt)...<OK> to continue...<Enter> 1 to stop.,0
*IF,stop,EQ,1,THEN
   *GO,:end
*ENDIF
!-----------------------------------------------------------------------
!- Defaults to .txt extension, append.
mtrx_pr,'nuts',,1,'model',1,1,5,1,'%-8C','X',1,1,5,4,'%6I'

*ASK,stop,(Look at appended part of nuts.txt)...<OK> to continue...<Enter> 1 to stop.,0
*IF,stop,EQ,1,THEN
   *GO,:end
*ENDIF
!-----------------------------------------------------------------------
!- Print columns of Matrix 2 in reverse order  [TBD]
!mtrx_pr,'nuts','txt',0,'model',1,1,5,1,'%-8C','X',1,5,5,1,'%6I'

!-----------------------------------------------------------------------
!- Print rows of Matrix 1 in reverse order  [TBD]
!mtrx_pr,'nuts','txt',0,'model',1,1,5,1,'%-8C','X',1,5,5,1,'%6I'

!-----------------------------------------------------------------------
!- defaults to current [jobname].txt location
mtrx_pr,,,0,'model',1,1,5,1,'%-8C','X',1,1,5,5,'%6I'

*ASK,stop,(No filename entered. Look at [jobname].[ext])...<OK> to continue...<Enter> 1 to stop.,0
*IF,stop,EQ,1,THEN
   *GO,:end
*ENDIF
!-----------------------------------------------------------------------
!- ERROR: fname not properly defined
mtrx_pr,nuts,'txt',1,'model',1,1,5,1,'%-8C','X',1,1,5,5,'%6I'


*ASK,stop,(Error in filename.  See [jobname].[ext] appended)...<OK> to continue...<Enter> 1 to stop.,0
*IF,stop,EQ,1,THEN
   *GO,:end
*ENDIF
!-----------------------------------------------------------------------
!- ERROR: M1 and M2 not arrays or table (forgot single quotes around name)
mtrx_pr,'nuts','txt',0,model,1,1,5,1,'%-8C',X,1,1,5,5,'%6I'

*ASK,stop,(Expected Error in matrix names)...<OK> to continue...<Enter> 1 to stop.,0
*IF,stop,EQ,1,THEN
   *GO,:end
*ENDIF
!-----------------------------------------------------------------------
!- ERROR: If two matrices defined, are the number of rows to be printed equivalent? 
mtrx_pr,'nuts','txt',0,'model',1,1,4,1,'%-8C','X',1,1,5,5,'%6I'

*ASK,stop,(Expected Error in matrix print rows)...<OK> to continue...<Enter> 1 to stop.,0
*IF,stop,EQ,1,THEN
   *GO,:end
*ENDIF
!-----------------------------------------------------------------------
!- ERROR: From and To do not make sense per matrices size
!  less than 1
mtrx_pr,'nuts','txt',0,'model',0,,,,'%-8C','X',-1,,,-100,'%6I'
!  greater than matrix size
mtrx_pr,'nuts','txt',0,'model',9,8,6,6,'%-8C','X',6,6,10,7,'%6I'

*ASK,stop,(Expected Error in matrix rows & columns)...<OK> to continue...<Enter> 1 to stop.,0
*IF,stop,EQ,1,THEN
   *GO,:end
*ENDIF
!-----------------------------------------------------------------------

:end
*set,stop
!