/COM,ANSYS MEDIA REL. 5.4 (8/20/97) REF. VERIF. MANUAL: REL. 5.4
/VERIFY,VM19
/SHOW
/PREP7
/TITLE,VM19-modified,VIBRATION ANALYSIS OF CANTILEVER BEAM WITH BASE EXCITATION
!
/COM  The vibration excitiation is input at the cantilever end (node 1).
/COM  The ampliude of DISPLACEMENT input is 2.00
!
!   Diagram of model:
!
!             +y  ^ 
!             |
!       ^    ///
!       |    ///          beam
!       |    ///----------------------------------  +x
!       |    ///
!       V    ///
!       
!          displacement
!      excitation 
!      {2.00 sin wt}
!
!
!
ET,1,BEAM4                         ! DEFINE ELEMENT TYPE
MP,EX,1,200E9                      ! DEFINE MATERIAL PROPERTIES
MP,NUXY,1,0.3
MP,ALPX,1,0.1E-5
MP,DENS,1,8000
R,1,4,1.333,1.333,2,2,0            ! DEFINE REAL CONSTANTS
RMORE,0,2.2496,1.177,1.177
N,1,0
N,101,10
FILL
E,1,2
EGEN,100,1,1
!d,1,all
FINISH

/SOLU
!  
ANTYPE,modal
!  
MXPAND,9, , ,yes
MODOPT,reduc
PSTRES,0
m,1,uy,101,1
!
solve
!
finish
!
/solu
!
antype,harmic           ! initiate harmonic analysis
hropt,msup          ! mode-superposition option
kbc,1               ! step boundary condition
harfrq,20,100           ! frequency range from 20 to 100 Hz
nsubst,3000         ! 1000 intervals in frequency range
dmprat,0.02
d,1,uy,2.00         ! apply load amplitude
!
save
solve
finish
!
/post26
!
file,harmonic,rfrq
prcplx,1
!
csys,0              ! Selected node 1
nsel,s,loc,x,2,,
*get,n1,node,,num,max
!
nsel,s,loc,x,4,,        ! Selected node 2
*get,n2,node,,num,max
!
nsel,s,loc,x,6,,        ! Selected node 3
*get,n3,node,,num,max
!
nsel,s,loc,x,8,,        ! Selected node 4
*get,n4,node,,num,max
!
nsel,s,loc,x,10,,       ! Selected node 5
*get,n5,node,,num,max
!
nsel,all
!
nsol,2,n1,u,y,disp1
nsol,3,n2,u,y,disp2
nsol,4,n3,u,y,disp3
nsol,5,n4,u,y,disp4
nsol,6,n5,u,y,disp5
!
/grid,1
/axlab,x,freq
/axlab,y,disp
plvar,2,3,4,5,6
finish
!